求AES文献-SPICE Simulation of Headphones and Earphones - AES专区 - 声学楼论坛

Poldy’s AKG headphone
.INCLUDE IEC711.cir
* sorta includes air gap impedances
* electrical model (from 45 mm driver)
VAeg 1 0 AC 1V DC 0V
Rew 1 2 124
Lew 2 3 900u
HBLU 3 4 VA2 4.50
VA1 4 0 AC 0V DC 0V
* mechanical model
HBLI 5 0 VA1 4.50
Lm 5 6 314u
Rm 6 7 13m
Cm 7 8 2.4e-3
ESDP 8 9 50 10 8.8e-4
VA2 0 9 AC 0V DC 0V
* acoustical model (in the middle)
FSDU 10 50 VA2 8.8e-4
VA3 0 30 AC 0V DC 0V
* acoustical model backward from membrane
** cavities behind passive membranes
C123 10 30 0.97u
** ports from C1 (RLs in parallel)
RB 10 11 5
LB 11 15 31m
R3 10 12 30
L3 12 15 2.9m
** back cavity -- same as front
CB 15 30 25u
** radiation impedance from the rear (1 cm)
Lrear 15 30 31.88
Crear 15 16 4.2787e-11
Rrear1 15 16 56.8168e+5
Rrear2 16 30 128.8327e+6
* acoustical model forward (to ear)
VA4 0 40 AC 0V DC 0V
** ear diaphragm cavity
C0 50 40 25u
** cushion
Rbb 50 51 6
Lbb 51 52 0.6m
Cbb 52 40 210u
** leak
R0 50 55 3
L0 55 56 3.0m
** radiation impedance
Lleak 56 40 31.88
Cleak 56 57 4.2787e-11
Rleak1 56 57 56.8168e+5
Rleak2 57 40 128.8327e+6
** passive membrane
Rpm 50 58 3.3
Lpm 58 59 0.3m
Cpm 59 40 530u
*
X1 50 60 40 IEC711
*Vindrum 50 40 AC 0V DC 0V
Voutdrum 60 40 AC 0V DC 0V
.AC DEC 20 10 10K
.print ac i(Voutdrum)
.END

* IEC711_Coupler (from B&K)
* 1 input
* 2 output
* 3 return (ground)
.SUBCKT IEC711 1 2 3
La4 1 51 82.9
Ca4 51 3 0.943e-12
Ra5 51 52 50.6e6
La5 52 53 9.4e3
Ca5 53 3 1.9e-12
La6 51 54 130.3
Ca6 54 3 1.479e-12
Ra7 54 55 31.1e6
La7 55 56 983.8
Ca7 56 3 2.1e-12
La8 54 2 133.4
Ca8 2 3 1.517e-12
.ENDS IEC711

REFERENCES
[1] C. Poldy, “Headphones,” in Loudspeaker and
Headphone Handbook, John Borwick, Ed., pp.
585–692. Focal Press, 2001.
[2] J. Borwick, Ed., Loudspeaker and headphone
handbook, 3rd ed., Focal Press, 2001.
[3] C. Poldy, “Headphone fundamentals,” in Conference
Record, AES 120th Convention, Paris,
France, June 21 2006.
[4] H. F. Olson, Dynamical Analogies, 2nd Ed.,
Van Nostrand, Princeton, N.J, 1958.
[5] Leo L. Beranek, Acoustics (revised Ed.), Amer
Inst of Physics, Dec. 1986.
[6] B. N. Locanthi, “Application of electric circuit
analogies to loudspeaker design problems,”
IRE Trans. Audio, vol. PGA-6, Mar. 1952,
Reprinted in J. Audio Eng. Soc. 9, 778-785 Nov.
1971.
[7] A. N. Thiele, “Loudspeakers in vented boxes,
parts and,” J. Audio Eng. Soc., vol. 19, pp.
382–392, May 1971, Also pp. 471-483 (June
1971).
[8] R. H. Small, “Direct-radiator loudspeaker system
analysis,” J. Audio Eng. Soc., vol. 20, pp.
383–395, June 1972.
[9] L. W. Nagel and D. O. Pederson, “(simulation
program with integrated circuit emphasis),”
Memorandum No. ERL-M382, University
of California, Berkeley, Apr. 1973.

[10] W. M. Leach, “Computer-aided electroacoustic
design with,” Journal of the Audio Engineering
Society, vol. 39, no. 7/8, pp. 551–563, July 1991.
[11] ITU, “Artificial ears,” P.57, ITU, Aug. 1996.
[12] S¨oren J¨onsson, Bin Liu, Lars B. Nielsen, and
Andreas Schuhmacher, “Simulation of couplers,”
in 114th Convention, Workshop 7, Amsterdam,
The Netherlands, March 23 2003, AES.
[13] E. A. G. Shaw and G. J. Theissen, “Acoustics
of circumaural earphones,” JASA, vol. 34, no.
9, pp. 1233–1246, Sept. 1962.
[14] K. Ohta, F. Matsuda, T. Tanaka, K. Ohnuki,
N. Miyaji, and H. Sato, “Open-back type headphone
with a detachable attachment,” U.S.
Patent 4041256, Granted Aug. 1977, Filed on
Apr. 30, 1976.
[15] R. Gorike, “Headphone,” U.S. Patent 4005278,
Granted Jan. 25 1977, Filed Sept. 15, 1975.
[16] R. Sapiejewski, “Supra aural active noise reduction
headphones,” U. S. Patent 6567525,
Granted May 20 2003, Filed June 17, 1994.
[17] G. R. Ruben and F. E. Heinrich, “Electroacoustic
transducers,” U. S. Patent 3013905, Granted
Dec. 1961, Filed Nov. 20, 1958.
[18] T. Asahi, “Dynamic electroacoustic transducer,”
U. S. Patent 3898598, Granted Aug.
5 1975, Filed Oct. 30, 1974.
[19] Y. Yokoyama, S. Watanabe, and K. Nageno,
“Ear piece transducer,” U.S. Patent 4736435,
Granted Apr. 5 1988, Filed August 3, 1985.
[20] M. Tikander, “Modeling the attenuation of a
loosely-fit insert headphone for augmented reality
audio,” in Proceedings of the 30th AES
Conference, Saariselk¨a, March 15-17 2007.
[21] P. N. Bakalos, R. Sapiejewski, and J. M.
Harlow, “Passive headphone equalizing,”
U.S. Patent Application 20080152162, Granted
2008, Filed June 2008.
[22] R. Sapiejewski, K. P. Annunziato, I. M. Collier,
W. W. Tice, and J. M. Harlow, “Earphones,”
U.S. Patent Application 20080002835, Granted
2008, Filed June 2008.

[23] S. J. Iseberg and D. L. Wilson, “High fidelity
insert earphones and methods of making same,”
U.S. Patent 5887070, Granted March 23 1999,
Filed Dec. 19, 1996.
[24] W.R. Kampinga, C. Bosschaart andY.H. Wijnant,
and A. deBoer, “The coupling of a hearing
aid loudspeaker membrane to visco-thermal air
layers,” in Fourteenth International Congress
on Sound and Vibration, ICSV14, July 2007.

主题：求AES文献-SPICE Simulation of Headphones and Earphones